Aims

// For LoRa:
#include <MKRWAN.h>
// For battery monitor:
#include "Adafruit_MAX1704X.h"
Adafruit_MAX17048 maxlipo;
// For battery charger
#include <Arduino_PMIC.h>
// For LowPower
#include "ArduinoLowPower.h"

LoRaModem modem;

// Please enter your sensitive data in the arduino_secrets.h tab
#include "arduino_secrets.h"

// Start of soil moisture code...
// initiialise some variables
// the sensor value is taken from the sensor pin (A0)
int sensorPin = A0;
int sensorValue;
int dryAnalogValue = 1023;
int wetAnalogValue = 0;
int DryValuePercent = 0;
int WetValuepercent = 100;
// ...end of soil moisture code

// initialises a variable for battery state of charge:
int cellPercent = 0;

// We need the details below to connect your device to LoRa
// Read arduino secrets
String appEui = APP_EUI;
String appKey = APP_KEY;

void setup() {
// Put your setup code here, to run once:

// Start of battery charger code...
if (!PMIC.begin()) {
Serial.println("Failed to initialize PMIC!");
while (1);
}

// Set the input current limit to 2 A and the overload input voltage to 3.88 V
if (!PMIC.setInputCurrentLimit(2.0)) {
Serial.println("Error in set input current limit");
}

if (!PMIC.setInputVoltageLimit(3.88)) {
Serial.println("Error in set input voltage limit");
}

// set the minimum voltage used to feeding the module embed on Board
if (!PMIC.setMinimumSystemVoltage(3.5)) {
Serial.println("Error in set minimum system volage");
}

// Set the desired charge voltage to 4.11 V
if (!PMIC.setChargeVoltage(4.2)) {
Serial.println("Error in set charge volage");
}

// Set the charge current to 375 mA
// the charge current should be defind as maximum at (C for hour)/2h
// to avoid battery explosion (for example for a 750mAh battery set to 0.375 A)
if (!PMIC.setChargeCurrent(0.375)) {
Serial.println("Error in set charge current");
}
Serial.println("Initialization done!");

if (!PMIC.enableCharge()) {
Serial.println("Error enabling Charge mode");
}
// End of battery charger code.

Serial.begin(9600);
while (!Serial && millis() < 10000); //This line is needed to work with batteries https://forum.arduino.cc/t/it-does-not-work-powered-by-2xaa-batteries/520097/5

// The code below connects your device to LoRa
if (!modem.begin(EU868)) { // change this to your regional band (eg. US915, AS923, ...)
Serial.println("Failed to start module");
while (1) {}
};

Serial.print("Your module version is: ");
Serial.println(modem.version());
Serial.print("Your device EUI is: ");
Serial.println(modem.deviceEUI());
int connected = modem.joinOTAA(appEui, appKey);

// Start of battery monitor code...
Serial.println(F("\nAdafruit MAX17048 simple demo"));

if (!maxlipo.begin()) {
Serial.println(F("Couldnt find Adafruit MAX17048?\nMake sure a battery is plugged in!"));
while (1) delay(10);
}
Serial.print(F("Found MAX17048"));
Serial.print(F(" with Chip ID: 0x"));
Serial.println(maxlipo.getChipID(), HEX);
// ...end of battery monitor code.

if (!connected) {
Serial.println("Something went wrong; are you indoors? Move near a window and retry");
while (1) {}
}
}

void loop() {
// put your main code here, to run repeatedly:

// Start of soil moisture code...
sensorValue = analogRead(sensorPin);
Serial.println("Analog Value : ");
Serial.println(sensorValue);
sensorValue = analogRead(sensorPin);
Serial.print("Analog moisture Value : ");
Serial.println(sensorValue);
int moistureValuePercent = map(sensorValue, dryAnalogValue,
wetAnalogValue, DryValuePercent, WetValuepercent);
Serial.print("moisture percent: ");
Serial.print(moistureValuePercent);
Serial.println("%");
if (moistureValuePercent == DryValuePercent)
{
Serial.println("plant is dry !! ");
}
else
{
Serial.println("plant is OK !! ");
}
// ...end of soil moisture code

// Start of battery monitor code...
cellPercent =(maxlipo.cellPercent());
Serial.print(F("Batt Voltage: ")); Serial.print(maxlipo.cellVoltage(), 3); Serial.println(" V");
Serial.print(F("Batt Percent: ")); Serial.print(maxlipo.cellPercent(), 1); Serial.println(" %");
Serial.println();
// ...end of battery monitor code.

byte payload[2]; // The [2] means we are sending two items in the array. Arrays start at zero.
payload[0] = moistureValuePercent; // Send soil moisture by LoRa.
payload[1] = cellPercent; // Send state of charge by LoRa.

delay(1000); // Gives it time to execute.

modem.beginPacket();
modem.write(payload,2); // The number after the word 'payload' is the number of items sent in the array above. If you add another item, increment this number.
int err = modem.endPacket(false);
if (err > 0) {
Serial.println("Data Sent");
} else {
Serial.println("Error");
}
Serial.print("soil moisture data sent is: ");
Serial.print("soil moisture % is: "); Serial.println(moistureValuePercent);
Serial.print("battery % is: "); Serial.println(cellPercent);

LowPower.deepSleep(1800000); // 30 minute intervals. This is the line we will be using when the sensor is in production mode.
//delay(300000); // This is the interval between each temperature and state of charge reading. The default is five minutes.
//delay(30000); // We can use 30 seconds while in testing mode.
}